abyul.com > Excel > Question & Answer - vba 메세지 창 제어

엑셀에 대해서 궁금한 것이 있으시면 마음껏 질문해주세요.

이 게시판은 아별닷컴 회원만 질문을 올릴 수 있습니다. 회원에게 주어지는 특권인셈이지요. 회원이 아닌 분들은 열람만 가능합니다.

글 수 822

vba 메세지 창 제어

VBA 조회 수 2354 추천 수 0 2012.10.10 10:29:36

고수가되고파 *.104.208.234 http://abyul.com/zbxe/111478

첨부된 예제의 C6셀과 C7 셀에는 함수계산 후 인위적으로 +1, -1이 계산되어져 있습니다.

이러한 것들을 제어하고자 코드가 기록되어져 있는데요.

매크로를 실행하면 이러한 것들을 수정할 것인지를 묻는 대화상자가 나옵니다.

첨부된 예제는 2번 나오는데요. 만약 100개라면 100번 대화상자가 나오게 됩니다.

100개의 셀에 +,- 값이 계산되어져도 대화상자는 1번만 나오도록(물론 1개의 대화상자이더라도 100개의 셀에 이상이 있다는 내용은 출력이 되어야 하구요)하려면 어디를 수정해야 하는지요?

이 게시물을...

예제(1007)2.xlsm [File Size:22.1KB/Download:28]

엮인글 :: http://abyul.com/zbxe/111478/9cd/trackback

2012.10.11 12:11:44
*.104.126.21

첨부파일이 없네요~

2012.10.11 12:49:04
*.104.208.234

헉!. 이런 실수를... 다시 올렸습니다.

2012.10.11 14:31:30
*.104.126.21

고수가되고파님..

아래와 같은 로직을 이용해보세요..

수식셀들을 순환하면서 수식에 +나 -가 있는 셀들을 rngSum이라는 가상의 영역 범위에 모았다가..

그 셀의 개수를 메시지박스에 띄워서 몇개가 있는지 표시하면 될 것 같습니다.

Option Explicit

Sub abFindAdjustedFormulaCells()
    Dim rngSrc As Range
    Set rngSrc = ActiveSheet.UsedRange
    On Error Resume Next
    Set rngSrc = rngSrc.SpecialCells(xlCellTypeFormulas, 23)

    If rngSrc Is Nothing Or Err.Number = 1004 Then
        MsgBox "현재 시트에는 수식셀이 없습니다."
        Exit Sub
    ElseIf Err.Number <> 1004 And Err.Number <> 0 Then
        MsgBox "알수 없는 에러가 발생하여 종료합니다."
        Exit Sub
    Else
        Dim r As Range, rngSum As Range
        For Each r In rngSrc
            If InStr(r.Formula, "+") Or InStr(r.Formula, "-") Then
                If rngSum Is Nothing Then
                    Set rngSum = r
                Else
                    Set rngSum = Union(rngSum, r)
                End If
            End If
        Next r
    End If

    On Error GoTo 0

    Dim msgResult As Long
    If rngSum Is Nothing Then
        MsgBox "임의로 조정된 수식이 없습니다."
    Else
        msgResult = MsgBox(rngSum.Cells.Count & "개의 수식이 임의로 조정되었습니다." & _
                        "수정하시겠습니까?", vbYesNo, " 수식 조정 여부 확인창")
        If msgResult = vbYes Then
            '### 수식을 수정하는 코드를 넣으세요..
        End If
    End If

End Sub