이 게시판은 아별닷컴 회원만 질문을 올릴 수 있습니다. 회원에게 주어지는 특권인셈이지요. 회원이 아닌 분들은 열람만 가능합니다.
댓글 '30'
쟈니님..
다른 분들이 사용하셔도 됩니다. ^^
파일 안에 Ahor 부분만 제거하지 않으시면 필요하신 분들에게 배포하셔서 같이 사용하셔도 됩니다.
파워포인트는 딴 세계라서요..
옆 동네죠. ㅎㅎ
파워포인트 버전도 만들어봤습니다.
(첨부파일을 여신 다음에 F5눌러 슬라이드쇼 상태에서 버튼을 클릭해야 작동합니다.
편집상태에서 Alt+F8누르시고 실행창에서 원하시는 기능을 선택하신 다음 실행버튼을 누르셔도 됩니다.)
다운로드 : abyul.com_20120618_SetOrRemovePassword.pptm
다만..
암호 일괄 제거시에.. 매 파일을 열때마다 읽기 암호를 물어보는 단점이 있네요.
파워포인트의 .open메서드에 password 옵션을 지원하지 않아서 그렇습니다. 역시 엑셀이 짱.. ㅋㅋ
도움이 되셨다니 기쁘네요..
아별닷컴 널리 홍보하시어 많은 분들이 지루한 문서 작업을 좀 더 편하게 하게 되길 바래봅니다.
감사합니다. ^^
미안하다님..
닉네임을 부를 수록 미안해지는 기분입니다. ㅎㅎ
좋은 자료 공유해주셔서 감사합니다.
암호 해제시에 파일을 오픈할때마다 암호를 물어보는데요..
아래처럼 비밀번호 옵션을 추가하면 파일을 열때마다 물어보지 않아서 편리합니다.
기존 코드
Set wb = Documents.Open(FileName:=.SelectedItems(lngCount))
수정 코드
Set wb = Documents.Open(FileName:=.SelectedItems(lngCount), passwordDocument:=strPW)
감사합니다. ^__^)b
쟈니님.. 안녕하세요?
현재 엑셀의 기본 기능에는 일괄 암호 설정 및 해제 방법이 없는 것으로 알고 있습니다.
추가기능으로 개발된 것도 발견하지 못했네요..(사실 안 찾아봤습니다. ㅋ)
그래서 제가 간단하게 만들어봤습니다.
첨부파일을 다운 받아 엑셀로 열고
버튼을 클릭하면 파일들을 선택해서 일괄 암호를 설정할 수 있습니다.
일괄 해제할 수 있는 기능도 추가했습니다.
도움이 되셨기를..
다운받기 : abyul.com_20120618_SetOrRemovePassword.xlsm
아래 코드도 참고하세요..
Option Explicit
Sub setPassword()
With Application.FileDialog(msoFileDialogFilePicker)
.Filters.Add "Excel 파일", "*.xls; *.xlsx; *.csv", 1
.InitialFileName = "*.xls*"
.Title = "Select Files to set password.. " & vbNewLine & _
"암호를 설정할 파일을 모두 선택하세요.. abyul.com"
If .Show = vbTrue Then
Dim strPW As String
strPW = InputBox("선택한 파일을 모두 " & _
"한가지 암호로 설정합니다." & vbNewLine & _
"사용할 암호를 입력하세요")
Application.ScreenUpdating = False
Application.DisplayAlerts = False
Dim lngCount As Long
Dim wb As Workbook
For lngCount = 1 To .SelectedItems.Count
Set wb = Workbooks.Open(Filename:=.SelectedItems(lngCount))
wb.Password = strPW
wb.Save
wb.Close
Next lngCount
Application.ScreenUpdating = True
Application.DisplayAlerts = True
End If
End With
End Sub
Sub removePassword()
With Application.FileDialog(msoFileDialogFilePicker)
.Filters.Add "Excel 파일", "*.xls; *.xlsx; *.csv", 1
.InitialFileName = "*.xls*"
.Title = "Select Files to remove password.. " & vbNewLine & _
"암호를 제거할 파일을 모두 선택하세요.. abyul.com"
If .Show = vbTrue Then
Dim strPW As String
strPW = InputBox("선택한 파일의 암호를 " & _
"모두 제거합니다." & vbNewLine & _
"기존에 설정된 암호를 입력하세요")
Application.ScreenUpdating = False
Application.DisplayAlerts = False
Dim lngCount As Long
Dim wb As Workbook
For lngCount = 1 To .SelectedItems.Count
Set wb = Workbooks.Open(Filename:=.SelectedItems(lngCount), Password:=strPW)
wb.Password = ""
wb.Save
wb.Close
Next lngCount
Application.ScreenUpdating = True
Application.DisplayAlerts = True
End If
End With
End Sub