Option Explicit

Public pointNumber  As String

Sub insertPicture()

    '엑셀 파일이 있는 경로를 변수로 지정합니다.
    Dim basePath As String
    basePath = ActiveWorkbook.Path

    '작업할 시트들을 변수로 지정합니다.
    '그래야 나중에 시트 이름을 바꿔도 아래 2줄만 바꾸면 되게끔요..
    Dim S_ps As Worksheet
    Set S_ps = Worksheets("표석대장")
    Dim S_js As Worksheet
    Set S_js = Worksheets("조사현황")

    '삼각점번호의 값을 masterCode라는 변수에 집어 넣지요~
    Dim masterCode As String
    masterCode = S_ps.Range("J5").Value

    '사진 삽입에 필요한 변수 정의
    Dim R As Range
    Dim strFile As String

        '사진을 삽입하기 전에 기존 사진을 제거합니다.
        S_ps.Select
        If ActiveSheet.DrawingObjects.Count > 0 Then
            Call deleteObject
        End If

    '표석 대장 시트에 표지 사진 입력
    Set R = S_ps.Range("G20:AJ42")
    strFile = basePath & "\images\" & masterCode & "표지.JPG"
    Call resizePic(S_ps, R, strFile)

        '사진을 삽입하기 전에 기존 사진을 제거합니다.
        S_js.Select
        If ActiveSheet.DrawingObjects.Count > 0 Then
            Call deleteObject
        End If

    '조사현황 시트에 근경 사진 입력
    Set R = S_js.Range("A3:M3")
    strFile = basePath & "\images\" & masterCode & "근경.JPG"
    Call resizePic(S_js, R, strFile)

    '조사현황 시트에 원경 사진 입력
    Set R = S_js.Range("A5:M5")
    strFile = basePath & "\images\" & masterCode & "원경.JPG"
    Call resizePic(S_js, R, strFile)
   
    S_ps.Select
    S_ps.Range("J5").Select
   
    pointNumber = Worksheets("표석대장").Range("J5").Value

End Sub

'시트에 이미지 삽입 후에 셀 사이즈에 맞게 이미지 조정.
' resizePic( 삽입할 시트, 삽입할 셀 영역, 삽입할 파일 이름 )
Sub resizePic(S As Worksheet, R As Range, strFile As String)
    S.Select
    R.Select
   
    Dim fileName As String
    fileName = Dir(strFile)
   
    If Len(fileName) > 0 Then
        S.Pictures.Insert(strFile).Select
        With Selection
            .Top = R.Top
            .Left = R.Left
            .Height = R.Height
            .Width = R.Width
        End With
    Else
        MsgBox "화일이 없어요~", vbInformation, "이미지 삽입 에러창"
        S.Range("j5").Select
        End
    End If
End Sub

'사진을 삽입하기 전에 기존 사진을 제거합니다.
Sub deleteObject()
    ActiveSheet.DrawingObjects.Select
    Selection.Delete
End Sub